;Double the lenght of Main variations and add a random variety to the velocity of the notes.
;This wil create a "human feel".
Define PartName1-4 String
Define Elongation Numeric
Define Octave Numeric
Define Dice Numeric
ForEachStyle
  PrintLine StyleName
  ForEachPart
    Let PartName1-4 = SubString PartName 1 4
    If PartName1-4 = 'Main' 
      Let Elongation = MeasuresInPart
      Let MeasuresInPart = Add MeasuresInPart Elongation
      ForEachTrack
        ForEachEvent
          If EventType <= 2 ;Note-on Note-off
            Let Measure = Add Measure Elongation
            InsertEvent
          EndIf
        NextEvent
        ForEachEvent
          If EventType = 1                         ;note on
            Let Dice = Random                      ;result 0 thru 999
            Let Dice = Divide Dice 50              ;result 0 thru 19  *** CUSTOMIZE HERE ***
            Let Dice = Subtract Dice 10            ;result -10 thru +9
            Let DataByte2 = Add DataByte2 Dice     ;modify velocity
            If DataByte2 < 1 
              Let DataByte2 = 1
            EndIf
            If DataByte2 > 127
              Let DataByte2 = 127
            EndIf
            UpdateEvent
          EndIf
        NextEvent
      NextTrack
    EndIf
  NextPart
  SaveStyle
NextStyle